UTL_SMTPの概要

DECLARE
  -- メールサーバー情報を定義する
  l_mailhost VARCHAR2(100) := 'smtp.example.com';  -- SMTPサーバーアドレス
  l_mail_conn UTL_SMTP.connection;                 -- 接続オブジェクト

  -- メールの内容
  l_from VARCHAR2(100) := 'sender@example.com';    -- 送信者メール
  l_to VARCHAR2(100) := 'receiver@example.com';    -- 受信者メール
  l_subject VARCHAR2(100) := 'テストメール';            -- メールの件名
  l_message VARCHAR2(4000) := 'これはOceanBaseデータベースからのテストメールです。';  -- メール本文
BEGIN
  -- SMTPサーバーへの接続を開始する
  l_mail_conn := UTL_SMTP.open_connection(l_mailhost, 25);  -- 25はSMTPサービスの標準ポート

  -- サーバーにHELOコマンドを送信する
  UTL_SMTP.helo(l_mail_conn, l_mailhost);

  -- メールの送信者を設定する
  UTL_SMTP.mail(l_mail_conn, l_from);

  -- メールの受信者を設定する
  UTL_SMTP.rcpt(l_mail_conn, l_to);

  -- データ転送を開始する
  UTL_SMTP.open_data(l_mail_conn);

  -- メールヘッダー情報を追加する
  UTL_SMTP.write_data(l_mail_conn, 'From: ' || l_from || UTL_TCP.crlf);
  UTL_SMTP.write_data(l_mail_conn, 'To: ' || l_to || UTL_TCP.crlf);
  UTL_SMTP.write_data(l_mail_conn, 'Subject: ' || l_subject || UTL_TCP.crlf);
  UTL_SMTP.write_data(l_mail_conn, UTL_TCP.crlf);  -- ヘッダーと本文を区切る空行

  -- メール本文を書き込む
  UTL_SMTP.write_data(l_mail_conn, l_message || UTL_TCP.crlf);

  -- データ転送を終了する
  UTL_SMTP.close_data(l_mail_conn);

  -- 接続を閉じる
  UTL_SMTP.quit(l_mail_conn);

  DBMS_OUTPUT.PUT_LINE('メール送信成功！');
EXCEPTION
  WHEN OTHERS THEN
    -- エラーが発生した場合、接続を閉じるよう試みる（既に開いている場合）
    IF UTL_SMTP.is_open(l_mail_conn) THEN
      UTL_SMTP.quit(l_mail_conn);
    END IF;

    -- 例外情報を表示する
    RAISE;
END;
/